^;^ 失落的微点

package
{
	import flash.display.DisplayObject;
	import flash.display.MovieClip;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.text.TextField;
	import flash.utils.getDefinitionByName;
 
	public class AdPlayer extends MovieClip
	{
		private var preText: TextField;
		public function AdPlayer()
		{
			stop();
 
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;
 
			preText = new TextField();
			addChild(preText);
 
			addEventListener(Event.ENTER_FRAME, onEnterFrame);
		}
 
		public function onEnterFrame(event:Event):void
		{
			graphics.clear();
 
			if (framesLoaded == totalFrames) {
				removeEventListener(Event.ENTER_FRAME, onEnterFrame);
				removeChild(preText);
				preText = null;
				nextFrame();
				onInit();
			} else {
				var percent: Number = root.loaderInfo.bytesLoaded / root.loaderInfo.bytesTotal;
 
				preText.textColor = 0xFFFFFF;
				preText.text = (percent * 100).toFixed() + " %";
 
				preText.x = (stage.stageWidth * percent - preText.textWidth) / 2;
				preText.y = (stage.stageHeight - preText.textHeight) / 2;
 
				graphics.beginFill(0);
				graphics.drawRect(0, stage.stageHeight / 2 - 10, stage.stageWidth * percent, 20);
				graphics.endFill();
			}
		}
 
		private function onInit() : void {
			var playerClass: Class = Class(getDefinitionByName("ImageGallery"));
			if (playerClass) {
				var playerInstance: Object = new playerClass();
				addChild(playerInstance as DisplayObject);
			}
		}
	}
}

package
{
	import com.biztv.player.PlayerContext;
 
	import flash.display.Sprite;
	import flash.events.Event;
 
	[Frame(factoryClass="AdPlayer")] // 此处为关键
	public class ImageGallery extends Sprite
	{
		protected var context: PlayerContext;
 
		public function ImageGallery()
		{
			addEventListener(Event.ADDED_TO_STAGE, onAddedToStage);
		}
 
		private function onAddedToStage(event: Event):void {
			removeEventListener(Event.ADDED_TO_STAGE, onAddedToStage);		
			initialize(this);
		}
 
		public function initialize(own: Sprite=null):void {
			removeEventListener(Event.ADDED_TO_STAGE, onAddedToStage);
 
			context = new PlayerContext(own); // 此处使用robotlegs框架
		}
	}
}